flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/master";
    flake-utils.url = "github:numtide/flake-utils";

    nixpkgs-mozilla = {
      url = "github:mozilla/nixpkgs-mozilla";
      flake = false;
    };

    naersk.url = "github:nmattia/naersk";
  };

  description = "thulani discord bot";

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    ...
  } @ inputs: (flake-utils.lib.eachDefaultSystem (system:
    let
      pkgs = import nixpkgs {
        inherit system;

        overlays = [
          (import inputs.nixpkgs-mozilla)

          (self: super: let
            rust = (super.rustChannelOf {
              channel = "nightly";
              date = "2021-01-01";
              sha256 = "9wp6afVeZqCOEgXxYQiryYeF07kW5IHh3fQaOKF2oRI=";
            }).rust.override {
              extensions = ["rust-src"];
            };
          in {
            cargo = rust;
            rustc = rust;
          })
        ];
      };

      naersk = (inputs.naersk.lib."${system}".override {
        inherit (pkgs) cargo rustc;
      });

      deps = with pkgs; [
        openssl
        pkgconfig
        libopus
        postgresql
      ];

      pkg = naersk.buildPackage {
        pname = "thulani";
        version = self.rev or "dirty";

        src = pkgs.lib.cleanSource ./.;

        cargoBuildOptions = old: old ++ [ "--offline" ];

        buildInputs = deps;
      };

    in {
      devShell = pkgs.mkShell {
        buildInputs = (with pkgs; [
          cargo
          rustc
        ]) ++ deps;
      };

      defaultPackage = pkg;

      defaultApp = {
        type = "app";
        program = "${pkg}/bin/thulani";
      };
    })
  );
}