flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/release-22.05";
    flake-utils.url = "github:numtide/flake-utils/master";

    nixpkgs-mozilla = {
      url = "github:mozilla/nixpkgs-mozilla/master";
    };

    naersk = {
      url = "github:nmattia/naersk/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  description = "thulani discord bot";

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    ...
  } @ inputs: (flake-utils.lib.eachDefaultSystem (system:
    let
      pkgs = import nixpkgs {
        inherit system;

        overlays = [
          (import inputs.nixpkgs-mozilla)
        ];
      };

      mkRust = extensions: (pkgs.rustChannelOf {
        channel = "nightly";
        date = "2021-10-26";
        sha256 = "1hLbypXA+nuH7o3AHCokzSBZAvQxvef4x9+XxO3aBao=";
      }).rust.override {
        inherit extensions;
      };

      buildToolchain = mkRust [];
      devToolchain = mkRust [
        "rust-analyzer"
        "rust-src"
        "clippy"
      ];

      naersk = pkgs.callPackage inputs.naersk {
        cargo = buildToolchain;
        rustc = buildToolchain;
      };

      deps = with pkgs; [
        openssl
        pkgconfig
        libopus
        postgresql
      ];

      inherit (pkgs) lib;

      pkg = naersk.buildPackage {
        pname = "thulani";
        version = self.rev or "dirty";

        src = lib.cleanSource ./.;

        nativeBuildInputs = deps;
        remapPathPrefix = true;
      };

    in {
      devShells.default = pkgs.mkShell {
        buildInputs = (with pkgs; [
          devToolchain
        ]) ++ deps;

        RUST_SRC_PATH = "${devToolchain}/lib/rustlib/src/rust";
      };

      packages.default = pkg;
      apps.default = {
        type = "app";
        program = "${pkg}/bin/thulani";
      };
    })
  );
}